Beginnen met AutoLISP

Wil je beginnen met AutoLISP en heb je tijd over tijdens de feestdagen kijk dan eens hoe deze routine werkt. Je zult de AutoCAD commando's snel herkennen wanneer je de code bestudeerd en zien dat er slecht een paar AutoLISP functies zoals (setq, (get...., (polar en (setvar nodig zijn om de commando's aan elkaar te koppelen.  AutoLISP is een redelijk eenvoudige taal die makkelijk te leren is en goed bruikbaar is bij het dagelijks werk met AutoCAD en nu dus ook AutoCAD LT.

Wil je er verder mee neem gerust in januari contact met ons op.

​Voor nu fijne feestdagen.
​

---

(defun C:KERSTBOOM ( / hoog breed waar lamp)
  (setq hoog  (getreal  "\nHoe hoog is de boom:"))
  (setq breed (getreal  "\nHoe breed is de boom"))
  (setq waar  (getpoint "\nWaar komt de boom te staan"))
  (setq lamp  (getint   "\nAantal lampjes"))
 (tekenboom waar hoog breed lamp)
)
;---------------------------------------------------------------------------
(defun tekenboom (p1 h b lamp / pt ps stam pl pr en p1 p2 p3 p4 p5)
  (setq pt (polar p1 (* 0.5 pi) h))
  (setq ps (polar p1 (* 0.5  pi) (* 0.2 h)))
  (setq stam (/ b 50.0))
  ;teken de stam en voet
  (setvar "PLINEWID" stam)
  (command ".PLINE" p1 ps "")
  (command ".PLINE" p1 (polar p1 (* 1.0 pi) (* 0.2 b)) "")
  (command ".PLINE" p1 (polar p1 (* 0.0 pi) (* 0.2 b)) "")
  (setvar "PLINEWID" 0)
  ;teken de kruin van de boom
  (setq pl (polar ps (* 1.0 pi) (* 0.5 b)))
  (setq pr (polar ps (* 0.0 pi) (* 0.5 b)))
  (command "PLINE" pl pr pt "Close")
  ;teken de lampjes in boom
  (command ".ZOOM" "E")
  (command ".OFFSET" stam (entlast) (polar p1 (* 0.5 pi) (* 0.5 h)) "")
  (setq en (entlast))  
  (command ".-HATCH" "P"  "G" "GR_LINEAR" 15 "Yes" "S" "Last" "" "")
  (command ".ERASE" en "")
  (setq p1 (polar pr (angle pr pt) (* (distance pr pt) (/ 0.9 3.0))))
  (setq p2 (polar pl (angle pl pt) (* (distance pr pt) (/ 1.1 3.0))))
  (setq p3 (polar pr (angle pr pt) (* (distance pr pt) (/ 1.8 3.0))))
  (setq p4 (polar pl (angle pl pt) (* (distance pr pt) (/ 2.2 3.0))))
  (setq p5 (polar pr (angle pr pt) (* (distance pr pt) (/ 2.5 3.0))))
  (command ".PLINE" pl p1 p2 p3 p4 p5 "")
  (setq en (entlast)) 
  (setvar "PDMODE" 34)
  (command ".DIVIDE" (entlast) lamp)
  (command ".ERASE" en "")
  ;plaats de wens
  (command ".TEXT" "A" (list (car pl)(cadr pt)) (list (car pr)(cadr pt)) "FIJNE FEESTDAGEN")
  (command ".ZOOM" "E")
)